しずくぶろぐ

競技ぷろぐらみんぐしたり、なんかしたりします

gnuplotでグラフを書いた #雫ぷよ

いつも試行錯誤しながらgnuplotを使っているので自分用にまとめます。

set terminal postscript eps enhanced
eps_file = "2_3.eps";
unset label 
set output eps_file
#eps fileで出力

set key font ",25"

set xlabel "k_x" font "Arial,30"
set ylabel "k_y"font "Arial,30"
#x軸 y軸の名前

set tics font "Arial,20"


set autoscale
#サイズを適当に

set size ratio -1
#軸のスケールを同じに

set parametric
#媒介変数表示

set xrange[-6:6]
set yrange[-6:6]
#グラフの範囲を指定

set xtics ('{/Symbol p}/a' pi,'0' 0, '-{/Symbol p}/a' -pi)
set ytics ('{/Symbol p}/a' pi,'0' 0, '-{/Symbol p}/a' -pi)
#目盛に数値をつける
#ギリシア文字も/Symbol ほにゃららで打てる

set label 1 "{/Symbol G}" font 'Arial,30' point pt 31 at 0,0
set label 2 "M" font 'Arial,30' point pt 31 at pi,pi
set label 3 "X" font 'Arial,30' point pt 31 at pi,0

plot [0:2*pi] (3*pi*pi)**(1.0/3)*cos(t),(3*pi*pi)**(1.0/3)*sin(t) with l lw 3 lt 1 title "circle",\
 pi,-pi+t with l lw 3 lt 2 notitle,\
 -pi,-pi+t  with l lw 3 lt 2 notitle,\
 -pi+t,pi with l lw 3 lt 2 notitle,\
-pi+t,-pi  with l lw 3 lt 2 title  "square"

#プロット、複数の線をプロットする場合は","で区切る。長くなって見辛いときは \で改行

このテキスト(名前をgraph1とする)を持っておいてターミナルで

gnuplot> load "graph1"

とすればepsファイルが吐き出されている。

f:id:kapt0nH:20200601180043p:plain

次の目標としてはデータを取得してからグラフを作るまでをFortranか何かでやってもらいたい